Hướng Dẫn Nội Dung Ôn Tập Tin 11- HKII- Năm Học 2011
(Tài liệu chỉ sử dụng với mục đích tham khảo)
A. CÁC THUẬT TOÁN
Thuật toán về số:
1.THUẬT TOÁN KIỂM TRA SỐ NGUYÊN TỐ
2.THUẬT TOÁN TÍNH TỔNG CÁC CHỮ SỐ CỦA MỘT SỐ NGUYÊN
3.THUẬT TOÁN EUCLIDE TÍNH UCLN
4.THUẬT TOÁN TÍNH TỔNG CÁC ƯỚC SỐ CỦA MỘT SỐ NGUYÊN
Thuật toán về vòng lặp:
5.THUẬT TOÁN TÍNH GIAI THỪA MỘT SỐ NGUYÊN
6.THUẬT TOÁN TÍNH HÀM MŨ
B. CÁC BÀI TẬP VỀ MẢNG 1 CHIỀU (có 3 bt)
C. CÁC BÀI TẬP VỀ XÂU KÍ TỰ (có 4 bt)


A.CÁC THUẬT TOÁN VỀ SỐ
1.THUẬT TOÁN KIỂM TRA SỐ NGUYÊN TỐ
Thuật toán của ta dựa trên ý tưởng: nếu n >1 không chia hết cho số nguyên nào trong tất cả các số từ 2 đến thì n là số nguyên tố. Do đó ta sẽ kiểm tra tất cả các số nguyên từ 2 đến có round(sqrt(n)), nếu n không chia hết cho số nào trong đó thì n là số nguyên tố.
Nếu thấy biểu thức round(sqrt(n)) khó viết thì ta có thể kiểm tra từ 2 đến n div 2.
Hàm kiểm tra nguyên tố nhận vào một số nguyên n và trả lại kết quả là true (đúng) nếu n là nguyên tố và trả lại false nếu n không là số nguyên tố.

Code:

function ngto(n:integer):boolean;
var i:integer;
begin
    ngto:=false;
    if n<2 then exit;
    for i:=2 to trunc(sqrt(n)) do
        if n mod i=0 then exit; {nếu n chia hết cho i thì n không là nguyên tố => thoát luôn}
    ngto:=true;
end;

Chú ý: Dựa trên hàm kiểm tra nguyên tố, ta có thể tìm các số nguyên tố từ 1 đến n bằng cách cho i chạy từ 1 đến n và gọi hàm kiểm tra nguyên tố với từng giá trị i.
2.THUẬT TOÁN TÍNH TỔNG CÁC CHỮ SỐ CỦA MỘT SỐ NGUYÊN
Ý tưởng là ta chia số đó cho 10 lấy dư (mod) thì được chữ số hàng đơn vị, và lấy số đó div 10 thì sẽ được phần còn lại. Do đó sẽ chia liên tục cho đến khi không chia được nữa (số đó bằng 0), mỗi lần chia thì được một chữ số và ta cộng dồn chữ số đó vào tổng.
Hàm tính tổng chữ số nhận vào 1 số nguyên n và trả lại kết quả là tổng các chữ số của nó:

Code:

function tongcs(n:integer): integer;
var s : integer;
begin
   s := 0;
   while n <> 0 do begin
      s := s + n mod 10;
      n := n div 10;
   end;
   tongcs := s;
end;

Chú ý: Tính tích các chữ số cũng tương tự, chỉ cần chú ý ban đầu gán s là 1 và thực hiện phép nhân s với n mod 10.
3.THUẬT TOÁN EUCLIDE TÍNH UCLN
Ý tưởng của thuật toán Euclide là UCLN của 2 số a,b cũng là UCLN của 2 số b và a mod b, vậy ta sẽ đổi a là b, b là a mod b cho đến khi b bằng 0. Khi đó UCLN là a.
Hàm UCLN nhận vào 2 số nguyên a,b và trả lại kết quả là UCLN của 2 số đó.

Code:

function UCLN(a,b: integer): integer;
var r : integer;
begin
   while b<>0 do begin
      r := a mod b;
      a := b;
      b := r;
   end;
   UCLN := a;
end;

Chú ý: Dựa trên thuật toán tính UCLN ta có thể kiểm tra được 2 số nguyên tố cùng nhau hay không. Ngoài ra cũng có thể dùng để tối giản phân số bằng cách chia cả tử và mẫu cho UCLN.
4.THUẬT TOÁN TÍNH TỔNG CÁC ƯỚC SỐ CỦA MỘT SỐ NGUYÊN
Để tính tổng các ước số của số n, ta cho i chạy từ 1 đến n div 2, nếu n chia hết cho số nào thì ta cộng số đó vào tổng. (Chú ý cách tính này chưa xét n cũng là ước số của n).

Code:

function tongus(n : integer): integer;
var i,s : integer;
begin
   s := 0;
   for i := 1 to n div 2 do
      if n mod i = 0 then s := s + i;
   tongus := s;
end;

Chú ý: Dựa trên thuật toán tính tổng ước số, ta có thể kiểm tra được 1 số nguyên có là số hoàn thiện không: số nguyên gọi là số hoàn thiện nếu nó bằng tổng các ước số của nó.
CÁC THUẬT TOÁN VỀ VÒNG LẶP
5.THUẬT TOÁN TÍNH GIAI THỪA MỘT SỐ NGUYÊN
Giai thừa n! là tích các số từ 1 đến n. Vậy hàm giai thừa viết như sau:

Code:

function giaithua(n : integer) : longint;
var i : integer; s : longint;
begin
   s := 1;
   for i := 2 to n do s := s * i;
   giaithua := s;
end;

6.THUẬT TOÁN TÍNH HÀM MŨ
Trong Pascal ta có thể tính ab bằng công thức exp(b*ln(a)). Tuy nhiên nếu a không phải là số dương thì không thể áp dụng được.
Ta có thể tính hàm mũ an bằng công thức lặp như sau:

Code:

function hammu(a : real; n : integer): real;
var s : real; i : integer;
begin
   s := 1;
   for i := 1 to n do s := s * a;
   hammu := s;
end;

B. CÁC BÀI TẬP VỀ MẢNG 1 CHIỀU
BÀI TẬP 1
Nhập vào một số n (5<=n<=10) và n phần tử của dãy a, 1a) In ra các phần tử là số nguyên tố của dãy.
b) Tính ước chung lớn nhất của tất cả các phần tử của dãy.
c) Sắp xếp dãy tăng dần và in ra dãy sau sắp xếp.
HƯỚNG DẪN
Ta nên chia chương trình thành các chương trình con, mỗi chương trình thực hiện một yêu cầu. Ngoài ra ta cũng viết thêm các hàm kiểm tra nguyên tố, hàm mũ, hàm UCLN để thực hiện các yêu cầu đó.
Chương trình như sau:
Khai báo dữ liệu:

Code:

uses crt;
var n : integer;
      a : array[1..10] of integer; {n<=10 nên mảng có tối đa 10 phần tử}

Thủ tục nhập dữ liệu, có kiểm tra khi nhập.

Code:

procedure nhap;
var i : integer;
begin
   clrscr;
   write('NHAP VAO SO PHAN TU N = ');
   repeat
      readln(n);
      if (5<=n) and (n<=10) then break; {nếu thoã mãn thì dừng vòng lặp}
      writeln('Khong hop le (5<=n<=10). Nhap lai!!!'); {ngược lại thì báo lỗi}
   until false;

   writeln('NHAP VAO N PHAN TU (1<ai<100)');
   for i := 1 to n do begin
      write('a',i,'=');
      repeat
         readln(a[i]);
         if (1<a[i]) and (a[i]<100) then break;
         writeln('Khong hop le. Nhap lai!!!');
      until false;
   end;
end;

Code:

function ngto(n : integer): boolean; {hàm kiểm tra nguyên tố, xem giải thích ở phần trên}
var i : integer;
begin
   ngto := false;
   if n < 2 then exit;
   for i := 2 to round(sqrt(n)) do
      if n mod i = 0 then exit;
   ngto := true;
end;

Thủ tục in các số nguyên tố của một mảng

Code:

procedure inngto;
var i :integer;
begin
   writeln('CAC PHAN TU NGUYEN TO TRONG DAY:');
   for i := 1 to n do            {duyệt qua mọi phần tử từ 1 đến n}
      if ngto(a[i]) then writeln(a[i]);      {nếu ai là nguyên tố thì in ra}
end;

Code:

function UCLN(a,b: integer): integer;
var r : integer;
begin
   while b<>0 do begin
      r := a mod b;
      a := b;
      b := r;
   end;
   UCLN := a;
end;

Thủ tục tính UCLN của các phần tử của một mảng

Code:

procedure TinhUC;
var i,u : integer;
begin
   u := a[1];            {u là UCLN của các phần tử từ 1 đến i}
   for i := 2 to n do u := UCLN(u,a[i]);    {là UCLN của các phần tử từ 1 đến i-1 và ai}
   writeln('UCLN cua ca day la:',u);       
end;

Thủ tục sắp xếp tăng dần các phần tử của một mảng:
procedure sxep;

Code:

var i,j,tg : integer;
begin
   for i := 1 to n-1 do
      for j := i + 1 to n do
         if a[i] > a[j] then begin
            tg := a[i]; a[i] := a[j]; a[j] := tg;
         end;
   writeln('DAY SAU KHI SAP XEP TANG DAN:');
   for i := 1 to n do writeln(a[i]);
end;

Chương trình chính: lần lượt gọi từng thủ tục

Code:

BEGIN
   nhap;
   inngto;
   tinhuc;
   tong;
   sxep;
END.

BÀI TẬP 2
Tìm phần tử nhỏ nhất, lớn nhất của một mảng (cần chỉ ra cả vị trí của phần tử).
HƯỚNG DẪN
Giả sử phần tử min cần tìm là phần tử k. Ban đầu ta cho k=1. Sau đó cho i chạy từ 2 đến n, nếu a[k] > a[i] thì rõ ràng a[i] bé hơn, ta gán k bằng i. Sau khi duyệt toàn bộ dãy thì k sẽ là chỉ số của phần tử min. (Cách tìm min này đơn giản vì từ vị trí ta cũng suy ra được giá trị).

Code:

procedure timmin;
var i, k : integer;
begin
   k := 1;
   for i := 2 to n do
      if a[k] > a[i] then k := i;
   writeln('Phan tu nho nhat la a[',k,']=',a[k]);
end;

Tìm max cũng tương tự, chỉ thay dấu so sánh.

Code:

procedure timmax;
var i, k : integer;
begin
   k := 1;
   for i := 2 to n do
      if a[k] < a[i] then k := i;
   writeln('Phan tu lon nhat la a[',k,']=',a[k]);
end;

BÀI TẬP 3
Tìm các phần tử thoả mãn 1 tính chất gì đó.
HƯỚNG DẪN
Nếu tính chất cần thoả mãn là cần kiểm tra phức tạp (chẳng hạn: nguyên tố, hoàn thiện, có tổng chữ số bằng 1 giá trị cho trước…) thì ta nên viết một hàm để kiểm tra 1 phần tử có tính chất đó không. Còn tính chất cần kiểm tra đơn giản (chẵn / lẻ, dương / âm, chia hết, chính phương…) thì không cần.
Sau đó ta duyệt qua các phần tử từ đầu đến cuối, phần tử nào thoả mãn tính chất đó thì in ra.
Ví dụ 1. In ra các số chính phương của một mảng:
Để kiểm tra n có chính phương không, ta lấy căn n, làm tròn rồi bình phương và so sánh với n. Nếu biểu thức sqr(round(sqrt(n))) = n là true thì n là chính phương.
Vậy để in các phần tử chính phương ta viết:

Code:

for i := 1 to n do begin
        if sqr(round(sqrt(a[i]))) = a[i] then writeln(a[i]);

Ví dụ 2. In ra các số hoàn thiện từ 1 đến n:
Để kiểm tra số có hoàn thiện ta dùng hàm tổng ước (đã có ở phần đầu).

Code:

for i := 1 to n do begin
        if tongus(i) = i then writeln(i);

Ví dụ 3. In ra các phần tử của mảng chia 3 dư 1, chia 7 dư 2:

Code:

for i := 1 to n do begin
        if (a[i] mod 3=1) and (a[i] mod 7=2) then writeln(a[i]);

Ví dụ 4. In ra các số có 3 chữ số, tổng chữ số bằng 20, chia 7 dư 2.
Ta dùng hàm tổng chữ số đã có ở trên:

Code:

for i := 100 to 999 do begin {duyệt qua mọi số có 3 chữ số}
        if (tongcs(i)=20) and (i mod 7=2) then writeln(i);

Chú ý: Nếu áp dụng với mảng 2 chiều thì cũng tương tự, chỉ khác là để duyệt qua mọi phần tử của mảng 2 chiều thì ta phải dùng 2 vòng for.

C. CÁC BÀI TẬP VỀ XÂU KÍ TỰ
BÀI TẬP 1
Nhập vào một xâu s khác rỗng và thực hiện chuẩn hoá xâu, tức là:
a) Xoá các dấu cách thừa
b) Chuyển những kí tự đầu từ thành chữ hoa, những kí tự khác thành chữ thường.
HƯỚNG DẪN
Chương trình như sau:

Code:

var s : string;
procedure chuanhoa(var s : string); {s là tham biến để có thể thay đổi trong chương trình con}
var i : integer;
begin
    while s[1]=' ' do delete(s,1,1); {xoá các kí tự cách thừa ở đầu xâu}
    while s[length(s)]=' ' do delete(s,length(s),1); {xoá các kí tự cách thừa ở cuối xâu}
{xoá các kí tự cách thừa ở giữa các từ: nếu s[i-1] là cách thì s[i] là dấu cách là thừa. Phải dùng vòng lặp for downto vì nếu trong quá trình xoá ta làm giảm chiều dài của xâu, nếu for to sẽ không dừng được.}
    for i := length(s) downto 2 do
        if (s[i]=' ') and (s[i-1]=' ') then delete(s,i,1);
{Chuyển kí tự đầu xâu thành chữ hoa}
    s[1] := Upcase(s[1]);
    for i := 2 to length(s) do
        if s[i-1]=' ' then s[i] := Upcase(s[i]) {Chuyển s[i] là kí tự đầu từ thành chữ hoa.}
        else
            if s[i] in ['A'..'Z'] then   {s[i] là kí tự chữ hoa không ở đầu một từ}
                s[i] := chr(ord(s[i]) + 32); {thì phải chuyển thành chữ thường}
end;

BEGIN
  write('Nhap vao 1 xau s:');
  readln(s);
  chuanhoa(s);
  writeln('Xau s sau khi chuan hoa:',s);
  readln;
END.

BÀI TẬP 2
Nhập vào một xâu x khác rỗng và thông báo xâu đó có phải là xâu đối xứng hay không?
HƯỚNG DẪN
Xâu đối xứng nếu nó bằng chính xâu đảo của nó. Vậy cách đơn giản nhất là ta sẽ xây dựng xâu đảo của x và kiểm tra xem nó có bằng x không. Để xây dựng xâu đảo của x, cách đơn giản nhất là cộng các kí tự của x theo thứ tự ngược (từ cuối về đầu).

Code:

Chương trình:
var x : string;
(************************************************)
function doixung(x : string) : boolean; {hàm kiểm tra xâu đối xứng}
var y : string;
    i : integer;
begin
    y := '';
{xây dựng y là xâu đảo của x, bằng cách cộng dần các kí tự của x vào y theo thứ tự ngược}
    for i := length(x) downto 1 do y := y + x[i];
{so sánh x và xâu đảo của nó}
    if x=y then doixung := true else doixung := false;
end;
BEGIN
    write('Nhap vao 1 xau:');
    readln(x);
    if doixung(x) then
        writeln('Xau doi xung!')
    else
        writeln('Xau khong doi xung!');
    readln;
END.

BÀI TẬP 3
Nhập vào một xâu s và đếm xem nó có bao nhiêu từ. Từ là một dãy các kí tự, cách nhau bởi dấu cách?
HƯỚNG DẪN
Cách đếm từ đơn giản nhất là đếm dấu cách: nếu s[i] là kí tự khác cách và s[i-1] là kí tự cách thì chứng tỏ s[i] là vị trí bắt đầu của một từ. Chú ý là từ đầu tiên của xâu không có dấu cách đứng trước.
Chương trình:

Code:

var s : string;
{Hàm đếm số từ của một xâu}
function sotu(s : string) : integer;
var i, dem : integer;
begin
{cộng thêm dấu cách phía trước xâu để đếm cả từ đầu tiên}
    s := ' ' + s; dem := 0;
    for i := 2 to length(s) do {s[i] là vị trí bắt đầu 1 từ}
        if (s[i-1]=' ') and (s[i]<>' ') then dem := dem + 1;
    sotu := dem;
end;
BEGIN
    write('Nhap vao 1 xau:');
    readln(s);
    writeln('So tu trong xau la:',sotu(s));
    readln;
END.

BÀI TẬP 4
Nhập vào một xâu s và in ra các từ của nó (Từ là một dãy các kí tự, cách nhau bởi dấu cách). Xâu có bao nhiêu từ là đối xứng?
HƯỚNG DẪN
Có nhiều cách để tách một xâu thành các từ. Cách đơn giản nhất tiến hành như sau:
1) Bỏ qua các dấu cách cho đến khi gặp một kí tự khác cách (hoặc hết xâu).
2) Ghi các kí tự tiếp theo vào xâu tạm cho đến khi gặp dấu cách hoặc hết xâu, khi đó ta được 1 từ.
3) Nếu chưa hết xâu thì quay lại bước 1.
Mỗi khi tìm được một từ, ta ghi luôn nó ra màn hình, nếu từ đó là đối xứng thì tăng biến đếm. Ta cũng có thể lưu các từ tách được vào một mảng nếu bài tập yêu cầu dùng đến những từ đó trong các câu sau.
Chương trình:

Code:

var s : string;
    dem : integer;
{Hàm kiểm tra từ đối xứng}
function doixung(x : string) : boolean;
var y : string;
    i : integer;
begin
    y := '';
    for i := length(x) downto 1 do y := y + x[i];
    if x=y then doixung := true else doixung := false;
end;
{Thủ tục thực hiện tách từ}
procedure tach;
var i, len : integer;
    t : string;
begin
    writeln('Cac tu trong xau:');
    i := 1; len := length(s);
    repeat
{B1: bỏ qua các dấu cách cho đến khi hết xâu hoặc gặp 1 kí tự khác cách:}
          while (s[i]=' ') and (i<=len) do inc(i);
          if i>=len then break; {nếu hết xâu thì dừng}
          t := '';         {t là biến tạm lưu từ đang tách}
{B2: lấy các kí tự khác cách đưa vào biến tạm cho đến khi hết xâu hoặc gặp 1 kí tự cách:}
          while (s[i]<>' ') and (i<=len) do begin
                t := t + s[i];
                inc(i);
          end;
{in ra từ vừa tách được và kiểm tra đối xứng}
          writeln(t);
          if doixung(t) then inc(dem);
    until i >= len;
    writeln('So tu doi xung trong xau:',dem);
end;
(************************************************)
BEGIN
    write('Nhap vao 1 xau:');
    readln(s);
    tach;
END.

Code: